Theory Code_Evaluation

(*  Title:      HOL/Code_Evaluation.thy
    Author:     Florian Haftmann, TU Muenchen
*)

header {* Term evaluation using the generic code generator *}

theory Code_Evaluation
imports Plain Typerep Code_Numeral
uses ("Tools/code_evaluation.ML")
begin

subsection {* Term representation *}

subsubsection {* Terms and class @{text term_of} *}

datatype "term" = dummy_term

definition Const :: "String.literal => typerep => term" where
  "Const _ _ = dummy_term"

definition App :: "term => term => term" where
  "App _ _ = dummy_term"

definition Abs :: "String.literal => typerep => term => term" where
  "Abs _ _ _ = dummy_term"

definition Free :: "String.literal => typerep => term" where
  "Free _ _ = dummy_term"

code_datatype Const App Abs Free

class term_of = typerep +
  fixes term_of :: "'a => term"

lemma term_of_anything: "term_of x ≡ t"
  by (rule eq_reflection) (cases "term_of x", cases t, simp)

definition valapp :: "('a => 'b) × (unit => term)
  => 'a × (unit => term) => 'b × (unit => term)" where
  "valapp f x = (fst f (fst x), λu. App (snd f ()) (snd x ()))"

lemma valapp_code [code, code_unfold]:
  "valapp (f, tf) (x, tx) = (f x, λu. App (tf ()) (tx ()))"
  by (simp only: valapp_def fst_conv snd_conv)


subsubsection {* Syntax *}

definition termify :: "'a => term" where
  [code del]: "termify x = dummy_term"

abbreviation valtermify :: "'a => 'a × (unit => term)" where
  "valtermify x ≡ (x, λu. termify x)"

locale term_syntax
begin

notation App (infixl "<·>" 70)
  and valapp (infixl "{·}" 70)

end

interpretation term_syntax .

no_notation App (infixl "<·>" 70)
  and valapp (infixl "{·}" 70)


subsection {* Tools setup and evaluation *}

lemma eq_eq_TrueD:
  assumes "(x ≡ y) ≡ Trueprop True"
  shows "x ≡ y"
  using assms by simp

use "Tools/code_evaluation.ML"

code_reserved Eval Code_Evaluation

setup {* Code_Evaluation.setup *}


subsection {* @{text term_of} instances *}

instantiation "fun" :: (typerep, typerep) term_of
begin

definition
  "term_of (f :: 'a => 'b) = Const (STR ''dummy_pattern'') (Typerep.Typerep (STR ''fun'')
     [Typerep.typerep TYPE('a), Typerep.typerep TYPE('b)])"

instance ..

end

instantiation String.literal :: term_of
begin

definition
  "term_of s = App (Const (STR ''STR'')
    (Typerep.Typerep (STR ''fun'') [Typerep.Typerep (STR ''list'') [Typerep.Typerep (STR ''char'') []],
      Typerep.Typerep (STR ''String.literal'') []])) (term_of (String.explode s))"

instance ..

end


subsubsection {* Code generator setup *}

lemmas [code del] = term.recs term.cases term.size
lemma [code, code del]: "HOL.equal (t1::term) t2 <-> HOL.equal t1 t2" ..

lemma [code, code del]: "(term_of :: typerep => term) = term_of" ..
lemma [code, code del]: "(term_of :: term => term) = term_of" ..
lemma [code, code del]: "(term_of :: String.literal => term) = term_of" ..
lemma [code, code del]: "(Code_Evaluation.term_of :: 'a::{type, term_of} Predicate.pred => Code_Evaluation.term)
  = Code_Evaluation.term_of" ..
lemma [code, code del]: "(Code_Evaluation.term_of :: 'a::{type, term_of} Predicate.seq => Code_Evaluation.term)
  = Code_Evaluation.term_of" ..

lemma term_of_char [unfolded typerep_fun_def typerep_char_def typerep_nibble_def, code]:
  "Code_Evaluation.term_of c =
    (let (n, m) = nibble_pair_of_char c
  in Code_Evaluation.App (Code_Evaluation.App
    (Code_Evaluation.Const (STR ''String.char.Char'') (TYPEREP(nibble => nibble => char)))
      (Code_Evaluation.term_of n)) (Code_Evaluation.term_of m))"
  by (subst term_of_anything) rule 

code_type "term"
  (Eval "Term.term")

code_const Const and App and Abs and Free
  (Eval "Term.Const/ ((_), (_))" and "Term.$/ ((_), (_))" and "Term.Abs/ ((_), (_), (_))"
     and "Term.Free/ ((_), (_))")

code_const "term_of :: String.literal => term"
  (Eval "HOLogic.mk'_literal")

code_reserved Eval HOLogic


subsubsection {* Numeric types *}

definition term_of_num_semiring :: "'a::semiring_div => 'a => term" where
  "term_of_num_semiring two = (λ_. dummy_term)"

lemma (in term_syntax) term_of_num_semiring_code [code]:
  "term_of_num_semiring two k = (if k = 0 then termify Int.Pls
    else (if k mod two = 0
      then termify Int.Bit0 <·> term_of_num_semiring two (k div two)
      else termify Int.Bit1 <·> term_of_num_semiring two (k div two)))"
  by (auto simp add: term_of_anything Const_def App_def term_of_num_semiring_def Let_def)

lemma (in term_syntax) term_of_nat_code [code]:
  "term_of (n::nat) = termify (number_of :: int => nat) <·> term_of_num_semiring (2::nat) n"
  by (simp only: term_of_anything)

lemma (in term_syntax) term_of_code_numeral_code [code]:
  "term_of (k::code_numeral) = termify (number_of :: int => code_numeral) <·> term_of_num_semiring (2::code_numeral) k"
  by (simp only: term_of_anything)

definition term_of_num_ring :: "'a::ring_div => 'a => term" where
  "term_of_num_ring two = (λ_. dummy_term)"

lemma (in term_syntax) term_of_num_ring_code [code]:
  "term_of_num_ring two k = (if k = 0 then termify Int.Pls
    else if k = -1 then termify Int.Min
    else if k mod two = 0 then termify Int.Bit0 <·> term_of_num_ring two (k div two)
    else termify Int.Bit1 <·> term_of_num_ring two (k div two))"
  by (auto simp add: term_of_anything Const_def App_def term_of_num_ring_def Let_def)

lemma (in term_syntax) term_of_int_code [code]:
  "term_of (k::int) = (if k = 0 then termify (0 :: int)
    else termify (number_of :: int => int) <·> term_of_num_ring (2::int) k)"
  by (simp only: term_of_anything)


subsubsection {* Obfuscation *}

print_translation {*
let
  val term = Const ("<TERM>", dummyT);
  fun tr1' [_, _] = term;
  fun tr2' [] = term;
in
  [(@{const_syntax Const}, tr1'),
    (@{const_syntax App}, tr1'),
    (@{const_syntax dummy_term}, tr2')]
end
*}


subsection {* Diagnostic *}

definition tracing :: "String.literal => 'a => 'a" where
  [code del]: "tracing s x = x"

code_const "tracing :: String.literal => 'a => 'a"
  (Eval "Code'_Evaluation.tracing")


hide_const dummy_term valapp
hide_const (open) Const App Abs Free termify valtermify term_of term_of_num_semiring term_of_num_ring tracing

end