Theory Option

(*  Title:      HOL/Option.thy
    Author:     Folklore
*)

header {* Datatype option *}

theory Option
imports Datatype
begin

datatype 'a option = None | Some 'a

lemma not_None_eq [iff]: "(x ~= None) = (EX y. x = Some y)"
  by (induct x) auto

lemma not_Some_eq [iff]: "(ALL y. x ~= Some y) = (x = None)"
  by (induct x) auto

text{*Although it may appear that both of these equalities are helpful
only when applied to assumptions, in practice it seems better to give
them the uniform iff attribute. *}

lemma inj_Some [simp]: "inj_on Some A"
by (rule inj_onI) simp

lemma option_caseE:
  assumes c: "(case x of None => P | Some y => Q y)"
  obtains
    (None) "x = None" and P
  | (Some) y where "x = Some y" and "Q y"
  using c by (cases x) simp_all

lemma UNIV_option_conv: "UNIV = insert None (range Some)"
by(auto intro: classical)


subsubsection {* Operations *}

primrec the :: "'a option => 'a" where
"the (Some x) = x"

primrec set :: "'a option => 'a set" where
"set None = {}" |
"set (Some x) = {x}"

lemma ospec [dest]: "(ALL x:set A. P x) ==> A = Some x ==> P x"
  by simp

declaration {* fn _ =>
  Classical.map_cs (fn cs => cs addSD2 ("ospec", @{thm ospec}))
*}

lemma elem_set [iff]: "(x : set xo) = (xo = Some x)"
  by (cases xo) auto

lemma set_empty_eq [simp]: "(set xo = {}) = (xo = None)"
  by (cases xo) auto

definition map :: "('a => 'b) => 'a option => 'b option" where
  "map = (%f y. case y of None => None | Some x => Some (f x))"

lemma option_map_None [simp, code]: "map f None = None"
  by (simp add: map_def)

lemma option_map_Some [simp, code]: "map f (Some x) = Some (f x)"
  by (simp add: map_def)

lemma option_map_is_None [iff]:
    "(map f opt = None) = (opt = None)"
  by (simp add: map_def split add: option.split)

lemma option_map_eq_Some [iff]:
    "(map f xo = Some y) = (EX z. xo = Some z & f z = y)"
  by (simp add: map_def split add: option.split)

lemma option_map_comp:
    "map f (map g opt) = map (f o g) opt"
  by (simp add: map_def split add: option.split)

lemma option_map_o_sum_case [simp]:
    "map f o sum_case g h = sum_case (map f o g) (map f o h)"
  by (rule ext) (simp split: sum.split)

enriched_type map: Option.map proof -
  fix f g
  show "Option.map f o Option.map g = Option.map (f o g)"
  proof
    fix x
    show "(Option.map f o Option.map g) x= Option.map (f o g) x"
      by (cases x) simp_all
  qed
next
  show "Option.map id = id"
  proof
    fix x
    show "Option.map id x = id x"
      by (cases x) simp_all
  qed
qed

primrec bind :: "'a option => ('a => 'b option) => 'b option" where
bind_lzero: "bind None f = None" |
bind_lunit: "bind (Some x) f = f x"

lemma bind_runit[simp]: "bind x Some = x"
by (cases x) auto

lemma bind_assoc[simp]: "bind (bind x f) g = bind x (λy. bind (f y) g)"
by (cases x) auto

lemma bind_rzero[simp]: "bind x (λx. None) = None"
by (cases x) auto

hide_const (open) set map bind

subsubsection {* Code generator setup *}

definition is_none :: "'a option => bool" where
  [code_post]: "is_none x <-> x = None"

lemma is_none_code [code]:
  shows "is_none None <-> True"
    and "is_none (Some x) <-> False"
  unfolding is_none_def by simp_all

lemma [code_unfold]:
  "HOL.equal x None <-> is_none x"
  by (simp add: equal is_none_def)

hide_const (open) is_none

code_type option
  (SML "_ option")
  (OCaml "_ option")
  (Haskell "Maybe _")
  (Scala "!Option[(_)]")

code_const None and Some
  (SML "NONE" and "SOME")
  (OCaml "None" and "Some _")
  (Haskell "Nothing" and "Just")
  (Scala "!None" and "Some")

code_instance option :: equal
  (Haskell -)

code_const "HOL.equal :: 'a option => 'a option => bool"
  (Haskell infix 4 "==")

code_reserved SML
  option NONE SOME

code_reserved OCaml
  option None Some

code_reserved Scala
  Option None Some

end